ctmu.oak

/#

A formalization of some key ideas from Chris Langan's Cognitive-Theoretic Model
of the Universe (CTMU).  In the comments below, ANKORT refers to the following
paper:

Langan, Christopher M. (2002). "The Cognitive-Theoretic Model of the Universe:
A New Kind of Reality Theory". Progress in Complexity, Information, and Design
1.2–1.3.

#/

# DEFINITIONS #################################################################

# We begin with the Reality Principle, a mutual definition of "real" and
# "reality" in terms of relevance.

# reality contains all and only that which is real
d1: axiom for all x, x is in reality iff x is real
# real means relevant to reality
d2: axiom for all x, x is real iff relevant_to[x, reality]

# self-contained means containing just what is relevant to it
d3: axiom for all S, self_contained[S] iff for all x, x is in S iff relevant_to[x,S]

# absolutely different means they have no property in common
d4: axiom for all x,y, absolutely_different[x,y] iff for no p, p[x] and p[y]

d5: axiom for all x, has_linguistic_structure[x] iff can_be_described[x]
d6: axiom for all x, language[x] iff has_linguistic_structure[x]

# syndiffeonic means exhibiting "difference-in-sameness"
d7: axiom for all S, syndiffeonic[S] iff for all x,y in S, not absolutely_different[x,y]

# closure of a system S under a binary predicate p
d8: axiom for all S,p, closed[S,p] iff for all x,y where p[x,y], x is in S iff y is in S

d9: axiom for all x, self_reading[x] iff closed[x, reads]
d10: axiom for all x, self_writing[x] iff closed[x, writes]
d11: axiom for all x, self_configuring[x] iff closed[x, configures]
d12: axiom for all x, self_processing[x] iff self_reading[x] and self_writing[x]

# distribution of a predicate over a system
d13: axiom for all p,S, distributed[p,S] iff for all x in S, p[x]

# self-distributed means distributed over itself
d14: axiom for all x, self_distributed[x] iff distributed[x,x]

d15: axiom for all x, infocognition[x] iff information[x] and self_processing[x]

d16: axiom for all x, SCSPL[x] iff x is a self_configuring self_processing language

d17: axiom for all x, omnipresent[x] iff self_distributed[x]
d18: axiom for all x, omniscient[x] iff self_reading[x]
d19: axiom for all x, omnipotent[x] iff self_configuring[x] and self_processing[x]

d20: axiom for all x, God[x] iff omnipresent[x] and omniscient[x] and omnipotent[x]

# PRINCIPLES ##################################################################

# We take these principles as axioms for convenience, but reducing them to
# definitions or more basic principles would be a good direction for future
# work.  See the ANKORT paper for statements and justifications.

# reality is all-inclusive (contains everything that exists) - ANKORT p. 16
p1: axiom for all x, x is in reality

# reality can be (linguistically) described - ANKORT p. 19
p2: axiom can_be_described[reality]

# topological-descriptive duality - ANKORT p. 25
p3: axiom for all S,x, x is in S iff S[x]

# language consists of information - ANKORT p. 33
p4: axiom for all language l and x in l, x is information

# in a self-contained language, information is self-processing - ANKORT p. 33
p5: axiom for all self_contained language l and information x in l, x is self_processing

# PROOFS ######################################################################

t1: reality is self_contained
proof
  for all x, x is in reality iff relevant_to[x, reality] by d1,d2
  so thesis by d3
end

syndiffeonesis: for all x,y, not absolutely_different[x,y]
proof
  for all x,y, real[x] and real[y] by p1,d1
  so thesis by d4
end

# Principle of Linguistic Reducibility
linguistic: reality is a language
proof
  can_be_described[reality] by p2
  so has_linguistic_structure[reality] by d5
  so thesis by d6
end

# Metaphysical Autology Principle (MAP)
map: for all p, closed[reality, p] by p1,d8

# Mind Equals Reality Principle (M=R)
mr: not absolutely_different[mind, reality] by syndiffeonesis

# Multiplex Unity Principle (MU)
mu: reality is syndiffeonic by syndiffeonesis,d7

# some consequences of MAP
t2: reality is self_configuring by map,d11
t3: reality is self_reading by map,d9
t4: reality is self_writing by map,d10
t5: reality is self_processing by t3,t4,d12

hology: reality is self_distributed
proof
  for all x in reality, x is reality by p3
  so distributed[reality, reality] by d13
  so thesis by d14
end

# Principle of Infocognitive Monism
for all x, infocognition[x]
proof
  1: reality is a self_contained language by t1,linguistic
  for all x in reality, x is information by 1,p4
  for all information x in reality, x is self_processing by 1,p5
  so thesis by p1,d15
end

scspl: reality is an SCSPL
proof
  reality is self_configuring by t2
  reality is self_processing by t5
  reality is a language by linguistic
  so thesis by d16
end

# existence of God
for some x, God[x]
proof
  reality is omnipresent by hology,d17
  reality is omniscient by t3,d18
  reality is omnipotent by scspl,d16,d19
  so thesis by d20
end
Oak Examples

ctmu.oak
